> Thanks Loki. By the way, the plane texture is copied from your "sphere on
> checkered plane" picture !
> My set has ridges too, but it is made of plastic and I thought the stone
> sets were smoother. Your remark about the greasy marks sounds great, but I
> don't get how to make the variations in the coefficients of specular
> roughness (I am still quite a beginner in textures). The texture for the
> black stones is simply :
>
>     normal { crackle scale <0.3,0.1,0.3>*0.1 turbulence 0.2 }
>     finish { phong 1 phong_size 15 }
>
> Should I use layered finish or something like that ?

I've knocked up the attached image to show you what I mean.  It's not great
because I haven't really done any detail on the texture, but you can see
the effect I was referring to.

The texture is made by creating two textures which vary only in their
reflective and specular properties, then making a texture which is a bozo
pattern of the two things.  Obviously you can do better with a more careful
map, but I just wanted to show you that general technique.  Here's the SDL:

#declare F1_WSTONE = texture {
  pigment {
    color rgb 0.9
  }
  finish {
    ambient 0
    diffuse 1
    specular 0.35
    roughness 0.01
    reflection { 0.1,0.3 exponent 0.5 }
  }
}

#declare F2_WSTONE = texture {
  pigment {
    color rgb 0.9
  }
  finish {
    ambient 0
    diffuse 1
    specular 0.25
    roughness 0.075
    reflection { 0.05,0.15 exponent 0.5 }
  }
}

#declare T_WSTONE = texture {
  bozo
  texture_map {
    [0 F1_WSTONE]
    [1 F2_WSTONE]
  }
  turbulence 0.5
  scale 0.1
  warp { turbulence 1 }
  scale <1,1,0.5>
  rotate <20,40,70>
}

It's very basic and doesn't really show off the result as well as it might -
it'd probably look better on a black stone actually - but that's the basic
idea.  Also the stone is a bit too reflective in my test, it looks a bit
metallic, but you can modify that easily along with the specular properties
as you need them.  I've used this technique before to produce a 'handled'
look on metal objects which would have worn and/or greasy spots through
contact with skin.  Just adds a little more realism and stops the textures
looking so clean.

I've also done the stone as two domes as I mentioned before.  That's:

#declare MR = 0.025;
#declare R = 0.575;

#declare STONE = object {
  intersection {
    sphere {
      y*MR,R
    }
    sphere {
      -y*MR,R
    }
  }
  translate y*0.55
  scale <1,0.5,1>
}
Anyway, hopefully that'll give you some inspiration on texturing.  It's just
one of those things, the more attention to detail you use the less CG the
effect.

L
-

Post a reply to this message

Attachments:
Download 'refldiff.jpg' (186 KB)

Preview of image 'refldiff.jpg'